0 REM **** BASIC V2+ DEMO 1 ****
1 REM **  BY MARK MARZINZIK   **
2 REM **************************
3 DIM XM(200),YM(200)
4 DEF FN X(X)=(X+1)/21*319
5 DEF FN Y(Y)=(10-Y)/20*199
6 DEF FN Y1(X)=11*EXP(-.1*X)*SIN(X)
9 REM ** NETZGRAFIK
10 #COLOUR,1,1,0
20 #HIRES,2
30 FOR X1=0 TO 320 STEP 40
35 IF X1=320 THEN X1=319
40 Y1=(X1-160)^2/200
50 FOR X2=0 TO 320 STEP 40:Y2=199
55 IF X2=320 THEN X2=319
60 #LINE,X1,Y1,X2,Y2
70 NEXTX2:NEXTX1
80 #TEXT,0,0,"NETZ MIT PARABELFOERMIG ANGEORDNETEN"
90 #TEXT,1,0,"PUNKTEN   (MIT DEN BEFEHLEN #COLOUR/"
100 #TEXT,2,0,"#HIRES/#LINE)":GOSUB105:GOTO120
105 #TEXT,4,1,"<TASTE>"
110 #KEYPRESS:#HIRES,2:RETURN
120 REM ** ROEHRENGRAFIK
130 FOR T=1 TO 10 STEP 0.2
140 X=INT(170+100*COS(T/2))
150 Y=INT(70+80*SIN(T/3))
160 #REC,X-20,Y-20,X+20,Y+20
170 NEXT T
171 #TEXT,0,0,"ROEHRENGRAFIK MIT DEM BEFEHL #REC"
180 GOSUB 105
190 REM ** BLUETEN-GRAFIK
210 FOR I=50 TO 100 STEP 5
220 FOR J=0 TO 6.4 STEP 0.1
230 W=I+60*COS(7*J)
240 X=160+W*COS(J):Y=100+W*SIN(J)/1.5
250 IF X>319 OR X<0 OR Y>199 OR Y<0 THEN 280
260 IF J<>0 THEN:#LINE,X1,Y1,X,Y
270 X1=X:Y1=Y:NEXTJ:NEXTI
280 #TEXT,0,0,"BLUETE ERZEUGT MIT #LINE"
290 GOSUB449
300 REM ** BALKENDIAGRAMM
301 #COLOUR,1,1,0:#HIRES,2
310 DATA"1966","8.8","1970","15.0","1974","20.8","1978","25.4","1982","27.2"
311 DATA"1983","28.6","1984","29.1"
320 I=0:FOR X1=20 TO 260 STEP 40:I=I+1
330 READ J$(I),W$(I)
340 Y2=170:X2=X1+20:Y1=Y2-2*VAL(W$(I))
350 #REC,X1,Y1,X2,Y2
360 A=X1+9:B=Y1-9:C=X2+9:D=Y2-9
370 #LINE,X1,Y1,A,B:#LINE,A,B,A+20,B:#LINE,A+20,B,X1+20,Y1:#LINE,X2,Y2,C,D
380 #LINE,C,D,A+20,B
390 NEXT
392 DATA16,2,15,8,13,12,12,17,12,22,11,27,11,33
400 FOR I=1 TO 7:READZ,S
410 #TEXT,Z,S,W$(I)
415 #TEXT,22,6*(I-1),J$(I)
420 NEXT
430 #TEXT,7,8,"S U B V E N T I O N E N"
440 #TEXT,8,8," DES BUNDES IN MRD DM"
445 #TEXT,0,0,"BALKENDIAGRAMM MIT #REC/#LINE/#TEXT"
446 GOSUB105:GOTO500
449 REM ** UNTERPROGRAMM FARBEN AENDERN
450 #TEXT,1,1,"*** MIT TASTEN 1/2/3 KOENNEN DIE FARBEN":R=1:H=1:Z=0
457 #TEXT,2,1,"    GEAENDERT WERDEN ***"
458 #TEXT,24,0,"TIPPE <4> UM WEITERZUMACHEN"
460 GETX$:IFX$=""THEN460
461 IFX$="1"THENR=R+1:IFR=16THENR=0
470 IFX$="2"THENH=H+1:IFH=16THENH=0
480 IFX$="3"THENZ=Z+1:IFZ=16THENZ=0
485 IFX$="4"THENRETURN
490 #COLOUR,R,H,Z
491 GOTO460
500 REM ** KREISDIAGRAMM
510 DATA"OSTBLOCK","32","JAPAN","38","WESTEUROPA","103","USA","155"
511 DATA"SONSTIGE","32"
520 #CIRCLE,162,100,50:C=0
525 #CIRCLE,162,100,15
530 FOR I=1 TO 5
540 READL$(I),Z$(I)
550 B=(VAL(Z$(I))/360)*2*(null)
560 C=C+B
570 X=162+50*COS(C):X1=162+15*COS(C)
580 Y=100+50*SIN(C):Y1=100+15*SIN(C)
590 #LINE,X1,Y1,X,Y
600 NEXT
610 #TEXT,12,19,"360"
620 DATA11,23,15,22,15,17,9,17,13,23
630 FORI=1TO5
640 READZ,S:#TEXT,Z,S,Z$(I)
650 NEXTI
655 DATA10,27,18,24,16,4,5,16,13,27
660 FOR I=1TO5:READZ,S:#TEXT,Z,S,L$(I):NEXTI
670 #TEXT,22,4,"INSTALLIERTE UNIVERSAL-COMPUTER"
680 #TEXT,23,13,"1982 IN MRD DM"
685 #TEXT,24,12,"(INSGESAMT 360)"
690 #TEXT,0,0,"KREISDIAGRAMM MIT #CIRCLE/#LINE/#TEXT"
700 GOSUB105
710 REM ** KURVENDARSTELLUNG
736 C=FNX(0):D=FNY(0)
740 #LINE,FNX(0),FNY(10),FNX(0),FNY(-10)
750 #LINE,FNX(0),FNY(0),FNX(20),FNY(0)
760 I=0:FOR X=0 TO 20 STEP0.1:I=I+1
761 A=FNX(X):B=FNY(FNY1(X))
770 #PLOT,1,A,B
775 XM(I)=A:YM(I)=B
780 NEXT
790 #LINE,FNX(0),FNY(0),XM(1),YM(1)
800 FORJ=1TOI-1
810 #LINE,XM(J),YM(J),XM(J+1),YM(J+1)
820 NEXT
830 #TEXT,0,1,"10":#TEXT,0,7,"GEDAEMPFTE SCHWINGUNG MIT"
840 #TEXT,1,7,"#PLOT/#LINE/#TEXT"
850 #TEXT,24,0,"-10":#TEXT,12,0," 0":#TEXT,13,38,"20":#TEXT,18,26,"<TASTE>"
860 #KEYPRESS:#HIRES,0:#MARGIN,14:#SCREEN,6:#PEN,1:PRINTCHR$(147)
861 #PLACE,10,14
870 PRINT"ALLES KLAR!":PRINT
880 #PEN,14:PRINT"ICH HOFFE,SIE HABEN GEFALLEN GEFUNDEN AN";
890 PRINT"BASIC V2+ !  SIE SEHEN, ES BIETET UNBE-"
900 PRINT"GRENZTE MOEGLICHKEITEN IN DER GRAFIKPRO-";
910 PRINT"GRAMMIERUNG."
920 END